Box2D for Flash Games: Create amazing and realistic physics-based Flash games using Box2D with this book and ebook.

In your Main function, add the following line:

var gravity:b2Vec2=new b2Vec2(0,9.81);

This introduces our first Box2D data type: b2Vec2.

b2Vec2 is a 2D column vector that is a data type, which will store x and y components of a vector. As you can see, the constructor has two arguments, both numbers, representing the x and y components. This way we are defining the gravity variable as a vector with x=0 (which means no horizontal gravity) and y=-9.81 (which approximates Earth gravity).

Physics says the speed of an object falling freely near the Earth's surface increases by about 9.81 meters per second squared, which might be thought of as "meters per second, per second". So assuming there isn't any air resistance, we are about to simulate a real-world environment. Explaining the whole theory of a falling body is beyond the scope of this book, but you can get more information by searching for "equations for a falling body" on Google or Wikipedia.

You can set your game on the move with the following line:

var gravity:b2Vec2=new b2Vec2(0,1.63);

You can also simulate a no gravity environment with the arguments set at (0,0):

var gravity:b2Vec2=new b2Vec2(0,0);

We also need to tell if bodies inside the world are allowed to sleep when they come to rest, that is when they aren't affected by forces. A sleeping body does not require simulation, it just rests in its position as its presence does not affect anything in the world, allowing Box2D to ignore it, and thus speeding up the processing time and letting us achieve a better performance. So I always recommend to put bodies to sleep when possible.

Add the following line, which is just a simple Boolean variable definition:

var sleep:Boolean=true;

And finally, we are ready to create our first world:

var world:b2World = new b2World(gravity,sleep);

Now we have a container to manage all the bodies and perform our dynamic simulation.

Time to make a small recap. At the moment, your code should look like the following:

package {
  import flash.display.Sprite;
  import Box2D.Dynamics.*;
  import Box2D.Collision.*;
  import Box2D.Collision.Shapes.*;
  import Box2D.Common.Math.*;
  public class Main extends Sprite {
    public function Main() {
      var gravity:b2Vec2=new b2Vec2(0,9.81);
      var sleep:Boolean=true;
      var world:b2World = new b2World(gravity,sleep);
    }
  }
}

Let's make some simple changes to our class:

package {
  import flash.display.Sprite;
  import flash.events.Event;
  import Box2D.Dynamics.*;
  import Box2D.Collision.*;
  import Box2D.Collision.Shapes.*;
  import Box2D.Common.Math.*;
  public class Main extends Sprite {
    public function Main() {
      var gravity:b2Vec2=new b2Vec2(0,9.81);
      var sleep:Boolean=true;
      var world:b2World = new b2World(gravity,sleep);
      addEventListener(Event.ENTER_FRAME,updateWorld);
    }
    private function updateWorld(e:Event):void {
      trace("my awesome simulation runs here");
    }
  }
}

Nothing new, we just added an ENTER_FRAME event, but we needed it in order to run the simulation inside the updateWorld function. If you have doubts regarding event handling with AS3, refer to the official Adobe docs or get Flash Game Development by Example, Packt Publishing, which will guide you to a step-by-step creation of pure AS3 games.

Box2D simulation works by simulating the world at discrete steps of time. This means the world gets updated at every time step. It's up to us to decide which time step we are going to use for our simulation. Normally, physics in games have a time step of 1/60 seconds. Anyway, as I am running the Flash movie at 30 fps, I am going to set a time step of 1/30 seconds.

The first line into the updateWorld function will be:

var timeStep:Number=1/30

Just defining a time step, is not enough. At every step, every physic entity is updated according to the forces acting on it (unless it's sleeping). The algorithm which handles this task is called constraint solver. It basically loops through each constraint and solves it, one at a time. If you want to learn more about constraints, search for "constraint algorithm" on Google or Wikipedia.

Where's the catch? While a single constraint is solved perfectly, it can mess with other constraints that have already been solved.

Think about two balls moving: in the real world, each ball position is updated at the same time. In a computer simulation, we need to loop through the balls and update their position one at a time. Think about a for loop that updates a ball at every iteration. Everything works as long as the balls do not interact with each other, but what happens if the second ball hits the first, whose position has already been updated? They would overlap, which is not possible in a rigid body simulation.

To solve this problem with a reasonable approximation, we need to loop over all the constraints more than once. Now the question is: how many times?

There are two constraint solvers: velocity constraint solver and position constraint solver . The velocity solver is used to move physic entities in the world according to their impulses. The position solver adjusts physic entities' positions to avoid overlap.

So it's obvious that the more iterations there are, the more accurate the simulation, and the lower will be the performance. I managed to handle more than 100 physic entities using 10 velocity and position iterations, although the author of Box2D recommends 8 for velocity and 3 for position.

It's up to you to play with these values. Meanwhile, I'll be using 10 iterations for both constraint solvers.

So here we go with two new variables:

var velIterations:int=10;
var posIterations:int=10;

Finally we are ready to call the Step method on the world variable to update the simulation.

To use world inside the updateWorld function, we need to declare world as a class-level variable, shown as follows:

package {
  import flash.display.Sprite;
  import flash.events.Event;
  import Box2D.Dynamics.*;
  import Box2D.Collision.*;
  import Box2D.Collision.Shapes.*;
  import Box2D.Common.Math.*;
  public class Main extends Sprite {
    private var world:b2World;
    public function Main() {
      var gravity:b2Vec2=new b2Vec2(0,9.81);
      var sleep:Boolean=true;
      world=new b2World(gravity,sleep);
      addEventListener(Event.ENTER_FRAME,updateWorld);
    }
    private function updateWorld(e:Event):void {
      var timeStep:Number=1/30;
      var velIterations:int=10;
      var posIterations:int=10;
      world.Step(timeStep,velIterations,posIterations);
    }
  }
}

Now we have our world configured and running. Unfortunately, it's a very boring world, with nothing in it. So in the next chapter, we are going to populate the world with all kinds of physic entities.

Just one last thing, after each step you need to clear forces, to let the simulation start again at the next step.

You can do it by adding the following line right after the Step method:

world.ClearForces();Your final code is shown as follows:

package {
  import flash.display.Sprite;
  import flash.events.Event;
  import Box2D.Dynamics.*;
  import Box2D.Collision.*;
  import Box2D.Collision.Shapes.*;
  import Box2D.Common.Math.*;
  public class Main extends Sprite {
    private var world:b2World;
    public function Main() {
      var gravity:b2Vec2=new b2Vec2(0,9.81);
      var sleep:Boolean=true;
      world=new b2World(gravity,sleep);
      addEventListener(Event.ENTER_FRAME,updateWorld);
    }
    private function updateWorld(e:Event):void {
      var timeStep:Number=1/30;
      var velIterations:int=10;
      var posIterations:int=10;
      world.Step(timeStep,velIterations,posIterations);
      world.ClearForces();
    }
  }
}

And now you are really ready to place some action in your Box2D World.